 

*******************************
***************Generates Tables 5 & 6
********************************

 cd C:\Users\mjaremski\Desktop\ReplicationFile\Data\

******Count each bank's number of respondents
 use "NYBS+.dta", clear
 keep if yr==1915
 preserve
 forvalues i=1/8 {
	keep bankNYCorr`i' locationNYCorr`i'
	rename bankNYCorr`i' bank
	rename locationNYCorr`i' location 
	save temp`i', replace
	restore
	preserve
	}
 restore 
 clear
 use temp1.dta, clear
 forvalues i=2/8 {
	append using temp`i'.dta
	}
  gen corr=1
 drop if bank==""
 collapse (sum) corr, by(bank location)
 save corr.dta, replace

******Obtain city-level population number for min capital calculation
 insheet using "NYCities.csv", clear
 drop county
 save temp.dta, replace

******Generate Variables for Regressions
 use "NYBS+.dta", clear

 joinby using corr.dta, unmatched(master)
 drop _merge

 replace corr=0 if corr==.

 gen deflator=deflate/12.85
 bysort bankid: egen endyr=max(yr)

 drop if beginyr>1913
 drop if endyr<1924

 drop if deposits==0 | loans==0 | cash==0
 drop if corresp==0
 drop if assets1914==.

 gen lnassets=ln(assets/deflator)
 gen loas=loans/(assets)
 gen cashas=(cash)/(assets)
 gen duefromall=duefrombanks+duefromfed
 gen dfallas=duefromall/assets

 bysort bankid: egen startyr=min(yr)

 xtset bankid yr

 gen nyshare=nyccorr/corresp
 gen relvalue=assets/(fedmembassetsnearby)

 drop if yr>1924

 rename Loan_Swing_34_percent loanswing

 gen distResCity=distNY
 replace distResCity=distBuff if yr>1919 & distBuff<distNY

 replace fedmembassetsnearby=ln(fedmembassetsnearby+1)

 gen corrdum=0
 replace corrdum=1 if corr>0

 gen temp=1
 bysort countycode: egen totalmembever=max(fedmembever)
 bysort countycode: egen totalcountyobs=total(temp)

 egen mintrust=min(trust), by(bankid)
 replace trust=mintrust

 replace location="NEW YORK" if location=="Brooklyn"
 replace location=upper(location)

 joinby state stateicp countycode location using temp.dta, unmatched(master)
 drop _merge

 egen mincapital=min(capital), by(bankid)
 replace mincap=25000 if mincap==.

 gen nomincap=(mincapital-mincap)/10000

**************Generate Table 5
 sort bankid yr

 gen fedmembint=0
 replace fedmembint=fedmemb if corrdum==1

 xi: xtreg loanswing fedmemb chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m1

 xi: xtreg loanswing fedmemb fedmembint chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m2

 lincom fedmemb+fedmembint


 xi: xtreg cashas fedmemb chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m3

 xi: xtreg cashas fedmemb fedmembint chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m4

 lincom fedmemb+fedmembint


 xi: xtreg dfallas fedmemb chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m5

 xi: xtreg dfallas fedmemb fedmembint chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m6

 lincom fedmemb+fedmembint


 xi: xtreg loas fedmemb chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m7

 xi: xtreg loas fedmemb fedmembint chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m8

 lincom fedmemb+fedmembint


 xi: xtreg lnassets fedmemb chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m9

 xi: xtreg lnassets fedmemb fedmembint chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m10

 lincom fedmemb+fedmembint

 esttab m1 m2 m3 m4 m5 m6 m7 m8 m9 m10 using Table5.csv, replace b(3) se(3) margin pr2 starlevels(* 0.10 ** 0.05 *** 0.01) brackets label title("Table 5") wrap order(fedmemb fedmembint chmemb distResCity fedmembassetsnearby relvalue corresp nyshare)



**************Generate Table 6
 gen yr2=yr
 replace yr2=. if fedmemb==0

 bysort bankid: egen minfed=min(yr2),

 gen yearsfed=0
 replace yearsfed=yr-minfed+1 if minfed~=.
 replace yearsfed=0 if yearsfed<0
 replace yearsfed=8 if yearsfed==9

 drop if yearsfed>5
 
 sort bankid yr

 xi: xtreg loanswing i.yearsfed chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m1

 xi: xtreg cashas i.yearsfed chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m2

 xi: xtreg dfallas i.yearsfed chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m3

 xi: xtreg loas i.yearsfed chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m4

 xi: xtreg lnassets i.yearsfed chmemb distResCity fedmembassetsnearby relvalue corresp nyshare i.yr, fe robust
 estimates store m5

 esttab m1 m2 m3 m4 m5 using Table6.csv, replace b(3) se(3) margin pr2 starlevels(* 0.10 ** 0.05 *** 0.01) brackets label title("Table 6") wrap order(_Iyearsfed_1 _Iyearsfed_2 _Iyearsfed_3 _Iyearsfed_4 _Iyearsfed_5 chmemb distResCity fedmembassetsnearby relvalue corresp nyshare)


